Reload Sheet Format
SOLIDWORKS Forums
5 months ago

Hi Guys,

 

I need a help regarding drawing sheet format.

The situation is when I update my sheet format I want to update my drawings.

So what I do is reload my drawings.

The step are

1. Right-click the sheet

2. Select Properties.

3. Click Reload

3. Click OK.

 

So it takes four (4) clicks to reload the drawing.

It's fine if it is only one but what I have sometimes 7 drawings to update.

 

I think macro will do the trick just one click of a button.

 

Hope you have that kind of macro

 

Thanks guys.

 

Cheers,


Categories: API∕Macros

Comments
Last comment By: MARCO TULIO RAMOS FILHO   Wed, 07 Mar 2018 19:09:24 GMT
Re: Reload Sheet Format

Jeff,

 

I don't think API has codes for the reload button yet. So the workaround is to set the sheet format to none and then switching back to same sheet format. I've not tested this method and not sure if this would delete notes, etc. from the sheet format.

 

Please vote for SPRs #:330668

By: Deepak Gupta  Thu, 15 May 2014 07:28:12 GMT
Re: Reload Sheet Format

You probably just need to set the sheet properties using the existing values.  This should reload the new template (I haven't tested this theory though.)

 

Check out this example from the help file: http://help.solidworks.com/2013/English/api/sldworksapi/Get_and_Set_Sheet_Properties_Example_VB.htm

 

Take out these lines:

' Switch projection property 

    bFirstAng = vSheetProps(4)

    vSheetProps(4) = Not bFirstAng

 

 

That should get the existing sheet properties, and then reapply them but with an updated template.

By: Patrick O'Hern  Thu, 15 May 2014 13:50:24 GMT
Re: Reload Sheet Format

Deepak,

 

Yeah I have that kind of process. I copied some codes.

So I have 2 macro button.

First macro setting the sheet format to none

Second macro reloading my updated sheet format.

 

 

Cheers,

By: Jeffrey Tongco  Thu, 15 May 2014 22:28:45 GMT
Re: Reload Sheet Format

Why don't you combine both of them OR share the codes/macro here and someone will help you out.

By: Deepak Gupta  Fri, 16 May 2014 14:27:59 GMT
Re: Reload Sheet Format

this is the first code

 

' **********************************************************************

' * PLEASE change the path/filename for the sheet templates (see below)

' **********************************************************************

' *

' * Macro changes the sheetformat (= the "paper" of your drawing) for

' * all sheets of the active drawing. You have to adjust the path and

' * the file names to the new sheet formats. After successfully changing

' * the sheetformat the drawing is saved with its current name.

' * ATTENTION: you CAN'T change the drawing template, this is not

' * possible. So with this macro you can't update document properties.

' * All sheet formats will be "userdefinied" after updating with this

' * macro. If you want to have the "standard" A-A0 formats and not

' * userdefinied you have to change the macro accordingly or use its

' * "compagnion" which reloads a standard sheettemplate

' *

' * This macro is intended to be used with PAC4SWX for batch reloading

' * of sheetformats, in case you changed you sheetformat with a new

' * company logo, new title block layout or similar. But it will also

' * word if fired from the GUI (taskplaner not tested, but should work;

' * but I would like to see you using PAC4SWX instead of taskplaner ;-))

' *

' * PAC4SWX - http://swtools.cad.de/prog_pac.htm

' *

' *

' * 17.12.2003 Stefan Berlitz

' * SolidWorks Solution Partner

' *    http://swtools.cad.de

' * Inoffizielle deutsche SolidWorks Hilfeseite

' *    http://solidworks.cad.de

' *

' **********************************************************************

Sub ReloadSheetFormat()

   

    Dim sheetformatpath(12) As String

    Dim sheetformatdir As String

       

    ' ************ EDIT path and file name HERE ************************

   

    ' After editing the sheetformats delete the next line or comment it

    'If MsgBox(msgtext(6), vbOKOnly, "Please Edit Macro") = vbOK Then End

   

    ' Path to directory with sheetformats

    sheetformatdir = "C:\ProgramData\SolidWorks\SolidWorks 2013\lang\english\sheetformat\New Template\"

    ' path to the various sheet formats from A to A0, you may also use

    ' full pathnames, but if they are all in teh same subdir it's easier this way

    sheetformatpath(0) = sheetformatdir & "temp_A.slddrt"

    sheetformatpath(1) = sheetformatdir & "temp_av.slddrt"

    sheetformatpath(2) = sheetformatdir & "temp_B.slddrt"

    sheetformatpath(3) = sheetformatdir & "temp_c.slddrt"

    sheetformatpath(4) = sheetformatdir & "temp_d.slddrt"

    sheetformatpath(5) = sheetformatdir & "temp_e.slddrt"

    sheetformatpath(6) = sheetformatdir & "temp_a4.slddrt"

    sheetformatpath(7) = sheetformatdir & "temp_a4v.slddrt"

    sheetformatpath(8) = sheetformatdir & "temp_a3.slddrt"

    sheetformatpath(9) = sheetformatdir & "temp_a2.slddrt"

    sheetformatpath(10) = sheetformatdir & "temp_a1.slddrt"

    sheetformatpath(11) = sheetformatdir & "temp_a0.slddrt"

     ' already user defined

    sheetformatpath(12) = sheetformatdir & "WS-A3.slddrt"

    ' ************************* EDIT END *******************************

 

 

    Dim swApp As Object

    Dim DrawingDoc As Object

    Dim Sheet As Object

   

    Dim Titel As String

    Dim Datei As String

    Dim temp As String

    Dim pfad As String

    Dim msgtxt As String

   

    Dim Name As String

    Dim paperSize As Long

    Dim templateIn As Long

    Dim scale1 As Double

    Dim scale2 As Double

    Dim firstAngle As Boolean

    Dim templateName As String

    Dim Width As Double

    Dim Height As Double

    Dim propertyViewName As String

    Dim i As Long

    Dim MySheetCount As Long

    Dim SheetNames As Variant

    Dim SheetProperties As Variant

   

    Const swDocDRAWING = 3

    Const swDwgTemplateCustom = 12

    Const swDwgTemplateNone = 13

   

    ' attach to SolidWorks

    Set swApp = CreateObject("SldWorks.Application")

   

    Set DrawingDoc = swApp.ActiveDoc

    If DrawingDoc Is Nothing Then

        ' check if document is open

        MsgBox "No Drawing Open"

        Exit Sub

    End If

   

    If (DrawingDoc.GetType <> swDocDRAWING) Then

        ' check if document is a drawing

        MsgBox "No Drawing Open"

        Exit Sub

    End If

 

    ' get sheet count and traverse all sheets to reload sheetfromat

    '

    MySheetCount = DrawingDoc.GetSheetCount

    SheetNames = DrawingDoc.GetSheetNames

    ' reset error messages

    msgtxt = ""

   

    For i = 0 To MySheetCount - 1

        ' activate next sheet

        If DrawingDoc.ActivateSheet(SheetNames(i)) Then

            ' attach to sheet object

            Set Sheet = DrawingDoc.GetCurrentSheet

            SheetProperties = Sheet.GetProperties

           

            ' first we have to set the sheet to use "no sheetformat", for SolidWorks

            ' wont reload a sheetformat if it is the same name as before

            Name = Sheet.GetName

            paperSize = SheetProperties(0)

            ' set NO SHEETFORMAT

            templateIn = swDwgTemplateNone

            scale1 = SheetProperties(2)

            scale2 = SheetProperties(3)

            firstAngle = CBool(SheetProperties(4))

            ' no sheetformat = no path

            templateName = ""

            ' but we need the sheet size

            Width = SheetProperties(5)

            Height = SheetProperties(6)

            propertyViewName = Sheet.CustomPropertyView

           

            retval = DrawingDoc.SetupSheet5( _

                        Name, _

                        paperSize, _

                        templateIn, _

                        scale1, _

                        scale2, _

                        firstAngle, _

                        templateName, _

                        Width, _

                        Height, _

                        propertyViewName, _

                        True)

            If retval = False Then

                msgtxt = "Error" & vbCrLf

            Else

           

                ' and now we set the new sheetformat; it is necessary to set

                ' USER DEFINIED sheetformat for SolidWorks will look for the

                ' standard templates temp_??.slddrt in your spefified folder

                ' if using the standard sheet sizes.

                templateIn = swDwgTemplateCustom

               

                ' get correct sheetformat for this size depending on the

                ' papersize, this will allow aleady userdefined sheetformats

                ' to properly be reloaded

                paperSize = GetSheetSizeFromPaperSize(Width, Height)

                templateName = sheetformatpath(paperSize)

               

                retval = DrawingDoc.SetupSheet5( _

                            Name, _

                            paperSize, _

                            templateIn, _

                            scale1, _

                            scale2, _

                            firstAngle, _

                            templateName, _

                            Width, _

                            Height, _

                            propertyViewName, _

                            True)

                If retval = False Then

                    ' ERROR : can't load new sheetformat

                    msgtxt = "Can't Load" & templateName & vbCrLf

                Else

                   

                    ' everything worked fine, no message here for automation

                   

                    ' save the document without backup

                    'If DrawingDoc.Save2(True) > 0 Then

                        ' error saving file

                        ' Fehler beim Speichern

                     '   msgtxt = msgtxt & msgtext(5) & vbCrLf

                    'End If

               

                End If

           

            End If

        Else

            msgtxt = "Something" & Name & vbCrLf

        End If

    Next i

   

    'SetDraftingStandard

    'SetCurrentLayer

    'If Len(msgtxt) Then

    '    MsgBox msgtxt

    'End If

    DrawingDoc.ViewZoomtofit2

    DrawingDoc.ForceRebuild3 False

End Sub

Function GetSheetSizeFromPaperSize(SheetWidth, SheetHeight)

    ' Function returns the SheetSize constant based on the width and heigth

    ' useful for userdefined sheetformats

  

    Const swDwgPaperAsize = 0

    Const swDwgPaperAsizeVertical = 1

    Const swDwgPaperBsize = 2

    Const swDwgPaperCsize = 3

    Const swDwgPaperDsize = 4

    Const swDwgPaperEsize = 5

    Const swDwgPaperA4size = 6

    Const swDwgPaperA4sizeVertical = 7

    Const swDwgPaperA3size = 8

    Const swDwgPaperA2size = 9

    Const swDwgPaperA1size = 10

    Const swDwgPaperA0size = 11

    Const swDwgPapersUserDefined = 12

   

    If (Round(SheetWidth, 4) = 0.2794) And (Round(SheetHeight, 4) = 0.2159) Then

        GetSheetSizeFromPaperSize = swDwgPaperAsize

    ElseIf (Round(SheetWidth, 4) = 0.2159) And (Round(SheetHeight, 4) = 0.2794) Then

        GetSheetSizeFromPaperSize = swDwgPaperAsizeVertical

    ElseIf (Round(SheetWidth, 4) = 0.4318) And (Round(SheetHeight, 4) = 0.2794) Then

        GetSheetSizeFromPaperSize = swDwgPaperBsize

    ElseIf (Round(SheetWidth, 4) = 0.5588) And (Round(SheetHeight, 4) = 0.4318) Then

        GetSheetSizeFromPaperSize = swDwgPaperCsize

    ElseIf (Round(SheetWidth, 4) = 0.8636) And (Round(SheetHeight, 4) = 0.5588) Then

        GetSheetSizeFromPaperSize = swDwgPaperDsize

    ElseIf (Round(SheetWidth, 4) = 1.1176) And (Round(SheetHeight, 4) = 0.8636) Then

        GetSheetSizeFromPaperSize = swDwgPaperEsize

    ElseIf (Round(SheetWidth, 4) = 0.297) And (Round(SheetHeight, 4) = 0.21) Then

        GetSheetSizeFromPaperSize = swDwgPaperA4size

    ElseIf (Round(SheetWidth, 4) = 0.21) And (Round(SheetHeight, 4) = 0.297) Then

        GetSheetSizeFromPaperSize = swDwgPaperA4sizeVertical

    ElseIf (Round(SheetWidth, 4) = 0.42) And (Round(SheetHeight, 4) = 0.297) Then

        GetSheetSizeFromPaperSize = swDwgPaperA3size

    ElseIf (Round(SheetWidth, 4) = 0.594) And (Round(SheetHeight, 4) = 0.42) Then

        GetSheetSizeFromPaperSize = swDwgPaperA2size

    ElseIf (Round(SheetWidth, 4) = 0.841) And (Round(SheetHeight, 4) = 0.594) Then

        GetSheetSizeFromPaperSize = swDwgPaperA1size

    ElseIf (Round(SheetWidth, 4) = 1.189) And (Round(SheetHeight, 4) = 0.841) Then

        GetSheetSizeFromPaperSize = swDwgPaperA0size

    Else

        GetSheetSizeFromPaperSize = swDwgPapersUserDefined

    End If

End Function

By: Jeffrey Tongco  Wed, 04 Jun 2014 04:04:39 GMT
Re: Reload Sheet Format

this is the second code

 

 

Option Explicit

 

 

Dim swApp As SldWorks.SldWorks

Dim Part As Object

 

 

Sub main()

 

 

Set swApp = New SldWorks.SldWorks

Set Part = swApp.ActiveDoc

Part.SetupSheet4 "Sheet1", 6, 12, 1, 1, False, _

"C:\ProgramData\SolidWorks\SolidWorks 2013\lang\english\sheetformat\New Template\WS-A3.slddrt", _

0.297, 0.21, "Default"

Part.EditSketch

End Sub

By: Jeffrey Tongco  Wed, 04 Jun 2014 04:05:36 GMT
Re: Reload Sheet Format

There is an error with that code.

 

I dont know why. 

Cheers

By: Jeffrey Tongco  Wed, 04 Jun 2014 04:06:46 GMT
Re: Reload Sheet Format

I think " we want to do manually", Macro will not suitable for this

By: Poornakkumar Palanisamy  Wed, 04 Jun 2014 04:51:06 GMT
Re: Reload Sheet Format

The best would be to set the template to NONE and then reapply the same format. I just tested it out and it seems to work.

 

What is location of your template and template name so that I can incorporate them in the macro for you.

By: Deepak Gupta  Wed, 04 Jun 2014 05:03:34 GMT
Re: Reload Sheet Format

Really?It works on your PC.

 

The location is C:\ProgramData\SolidWorks\SolidWorks 2013\lang\english\sheetformat\New Template

 

And the file name is WS-A3.slddrt

 

I already replace the path in the code but what happens is when I click the macro button for that

the template is set to NONE afterwards nothing happens.

So I have the second macro to reload my new template.

 

I'll wait for the reply

 

Thanks

By: Jeffrey Tongco  Wed, 04 Jun 2014 23:44:27 GMT
Re: Reload Sheet Format

Jeff,

 

Try this macro. Please try it on sample files first.

 

This has been tested on SW2014 SP3 Win 7 x64. So in case you've lower version of SW, you may need to fix the reference libraries in the macro.

By: Deepak Gupta  Thu, 05 Jun 2014 09:42:50 GMT
Re: Reload Sheet Format

Deepak,

 

I got error in in this part

 

Sub main()

 

 

Dim swApp           As SldWorks.SldWorks

 

I dont know why.  I am using SolidWorks 2013 SP3

 

Cheers,

By: Jeffrey Tongco  Wed, 11 Jun 2014 05:58:21 GMT
Re: Reload Sheet Format

Hey Deepak,

 

Finally, it works!!

 

Thank you very much for the help.

 

Till next time

 

Cheers,

By: Jeffrey Tongco  Wed, 11 Jun 2014 22:13:42 GMT
Re: Reload Sheet Format

How can we get it to also update additional sheets?

 

If i go to sheet 2 and use the macro, it takes me back to the first sheet.

By: Nicole Walden  Mon, 16 Jun 2014 21:04:49 GMT
Re: Reload Sheet Format

Do you want to change all sheets OR only second sheet?

By: Deepak Gupta  Tue, 17 Jun 2014 08:23:38 GMT
Re: Reload Sheet Format

Just the active sheet if that's possible.

By: Nicole Walden  Tue, 17 Jun 2014 18:17:05 GMT
Re: Reload Sheet Format

Try the attached one. Make sure you've changed the sheet format path and name. Don't forget to add \ at the end of the sheet format path.

 

P.S. I've added version for SW2013 and SW2014.

By: Deepak Gupta  Wed, 18 Jun 2014 03:55:53 GMT
Re: Reload Sheet Format

Deepak, you rock! 

 

I might just have to find some more roller coasters to take you on, as a thank you :-)

By: Nicole Walden  Wed, 18 Jun 2014 15:33:24 GMT
Re: Reload Sheet Format

Hello Deepak,

 

I tried your macro and it works great for sheet one but it won't reload the sheet format of sheet 2 and so on.  Even if I goto sheet 2 and run the macro it jumps back to sheet 1 and reloads the format for that sheet only.

 

Garret

By: Garret Hansen  Wed, 17 Sep 2014 19:55:22 GMT
Re: Reload Sheet Format
By: Deepak Gupta  Thu, 18 Sep 2014 09:48:46 GMT
Re: Reload Sheet Format

Hey Deepak,

 

How to change the codes so that I could change all sheets in the drawing?

 

Thanks

 

Jeffrey

By: Jeffrey Tongco  Mon, 09 Feb 2015 03:45:27 GMT
Re: Reload Sheet Format

Check this one for all sheets: Re: Reload Sheet Format

By: Deepak Gupta  Mon, 09 Feb 2015 03:54:50 GMT
Re: Reload Sheet Format

Deepak,

 

I think that version is for 2014.

 

I'm getting an error for it.

 

How do you change it for 2013 version.

 

Cheers

By: Jeffrey Tongco  Mon, 09 Feb 2015 06:06:29 GMT
Re: Reload Sheet Format

Change the macro references to SW2013. Follow this video Fix-Update SOLIDWORKS Macro References

By: Deepak Gupta  Mon, 09 Feb 2015 06:25:40 GMT
Re: Reload Sheet Format

Deepak,

 

Video was very helpful thanks.

 

But the macro does not perform the function that reload all drawing sheets.

 

How is that?

 

Cheers,

By: Jeffrey Tongco  Mon, 09 Feb 2015 06:34:26 GMT
Re: Reload Sheet Format

Can you upload one sample drawing with older sheet format and your new sheet format that I can test/check the macro on.

By: Deepak Gupta  Fri, 06 Mar 2015 16:24:37 GMT
Re: Reload Sheet Format

Hey Deepak,

 

I've checked this link and tried to my PC.

What I get is this

 

 

I already change the path for the templates.

What else needs to be changed on the codes?

 

Also I don't understand the post condition of the macro.

 

Please help me to understand it.

 

Cheers,

 

Jeffrey

By: Jeffrey Tongco  Mon, 09 Mar 2015 23:51:47 GMT
Re: Reload Sheet Format

You need to change the template path/name in the macro and save that. And when you run the macro it asks you to select a folder which contains the drawings whose drawing format you need to change. Once you select the folder,macro will open each drawing file in that selected folder and will updated the sheet format.

By: Deepak Gupta  Tue, 10 Mar 2015 05:02:03 GMT
Re: Reload Sheet Format

Hey,

 

I've done what you instructed.

The macro process for each sheet but when you look at it while it is processing, the sheet content does not change and the drawing shut down.

By: Jeffrey Tongco  Tue, 10 Mar 2015 06:26:47 GMT
Re: Reload Sheet Format

It will open, process and close the drawing and then move to process next drawing. Once the macro has updated all the drawings, did you checked those drawing by opening again.

By: Deepak Gupta  Tue, 10 Mar 2015 06:42:04 GMT
Re: Reload Sheet Format

Ooh that's why.But when I checked the drawing all the drawings did not change.

By: Jeffrey Tongco  Tue, 10 Mar 2015 07:20:13 GMT
Re: Reload Sheet Format

Can you add the upload updated macro, one drawing with older sheet format and the new sheet format.

 

In case you can't upload all then do upload the updated macro so that I can verify the changes made.

By: Deepak Gupta  Tue, 10 Mar 2015 08:31:52 GMT
Re: Reload Sheet Format

I uploaded the macro updated.

 

Old sheet WS-A3-copy.slddrt

New sheet WS-A3.slddrt

 

Cheers,

By: Jeffrey Tongco  Tue, 10 Mar 2015 08:38:37 GMT
Re: Reload Sheet Format

The changes are correct and macro worked perfectly for me. Can you please verify the drawings again.

 

Please note that if you're older sheet  format and new sheet format have same name then the macro won't work.

By: Deepak Gupta  Tue, 10 Mar 2015 09:12:48 GMT
Re: Reload Sheet Format

It works now on my PC.

 

I use same name that's why it doesn't work.

 

Much appreciate your work.

 

Cheers,

By: Jeffrey Tongco  Tue, 10 Mar 2015 23:35:23 GMT
Re: Reload Sheet Format

Hey Deepak,

 

I am replying to an old message here..but I am trying to use this macro to update all the sheets in my drawing. It's currently only updating the first sheet. Any suggestions?

 

Thanks

By: Will Brumas  Wed, 06 Sep 2017 13:20:01 GMT
Re: Reload Sheet Format
By: Deepak Gupta  Wed, 06 Sep 2017 14:54:04 GMT
Re: Reload Sheet Format

Hi Deepak,

 

These macros work great with SW 2017 but I noticed that a couple of drawing sheet properties get changed as well:

 

1. Type of projection: Changes from First angle to Third angle.

2. Zone Parameters Tab -> Region: Changes from Sheet to Margins (do not know exactly what this is used for, though).

 

Any chance you know why this happens?

 

Thanks in advance.

Regards

Peter

By: Peter Larsen  Tue, 19 Sep 2017 06:58:55 GMT
Re: Reload Sheet Format

If you have all drawings in First angle, then change False to True in both of these lines

 

'Set the sheet format to NONE

    swModel.SetupSheet5 swSheet.GetName, swDwgPapersUserDefined, swDwgTemplateNone, vSheetProps(2), vSheetProps(3), False, "", 0.4318, 0.2794, "Default", True

   

    'Reload the sheet format from the speicifed location

    swModel.SetupSheet5 swSheet.GetName, swDwgPapersUserDefined, swDwgTemplateCustom, vSheetProps(2), vSheetProps(3), False, sTemplatePath & sTemplateName, 0.4318, 0.2794, "Default", True

 

I'll check the other issue and let you know.

By: Deepak Gupta  Tue, 19 Sep 2017 18:53:06 GMT
Re: Reload Sheet Format

Thank you very much Deepak!

Looking forward to the reply about the 2nd issue.

 

I have been trying without luck to modify the attached macro (made by you) to only reload the active sheet since I have to exclude sheets with certain names.

Would it be possible for you to modify it, so it only reloads the active sheet or even better, exclude sheets with specific name(s)?

 

Maybe I am asking for too much?

Regards

Peter

By: Peter Larsen  Thu, 21 Sep 2017 13:45:09 GMT
Re: Reload Sheet Format

Peter Larsen wrote:

 

Would it be possible for you to modify it, so it only reloads the active sheet or even better, exclude sheets with specific name(s)?

Both of these are possible.

By: Deepak Gupta  Thu, 21 Sep 2017 14:08:18 GMT
Re: Reload Sheet Format

Hi Deepak,

 

Did you get a chance to look at my 2nd point?

1. Type of projection: Changes from First angle to Third angle.

2. Zonejavascript:; Parameters Tab -> Region: Changes from Sheet to Margins (do not know exactly what this is used for, though).

It was about the attached macro where a drawing sheet setting is changed.

Besides that, are there any other risks/ changes that this macro does besides updating the active drawing sheet format? I would like to be 100% sure before I start using it.

 

Thank you very much.

/Peter

By: Peter Larsen  Fri, 24 Nov 2017 12:09:07 GMT
Re: Reload Sheet Format

Peter Larsen wrote:

 

Zone Parameters Tab -> Region: Changes from Sheet to Margins (do not know exactly what this is used for, though).

Sorry for the delay on getting back to you. Check this video about zone and their usage SOLIDWORKS Drawing Zones

 

Macro do not change the zone settings  but it will drive that setting from the new sheet format (which is being used to replace the older one)

 

Besides that, are there any other risks/ changes that this macro does besides updating the active drawing sheet format?

I've not seen any issues in using this macro but still advise to use on some sample files to be sure.

By: Deepak Gupta  Sat, 25 Nov 2017 08:35:26 GMT
Re: Reload Sheet Format

Thanks, Deepak! I know you are a busy man!

But I must say that there is something happening when using the macro. It does change the Region from Sheet to Margins.

When I update manually with same sheet format it does not change to Margins. Maybe it somehow resets that setting...?

However, it doesn´t matter - I can still use the macro as it currently is.

 

Thanks again!

/Peter

By: Peter Larsen  Mon, 27 Nov 2017 13:23:56 GMT
Re: Reload Sheet Format

Peter Larsen wrote:

 

But I must say that there is something happening when using the macro. It does change the Region from Sheet to Margins.

I set the zone as needed and then saved out the new sheet format. And then using macro didn't changed that setting.

 

If you can share your files I can try to check those settings on your files..

By: Deepak Gupta  Mon, 27 Nov 2017 18:41:08 GMT
Re: Reload Sheet Format

Here is the one fixed for SW2013, can you try it out.

 

Was a typo, fixed that.

 

By: Deepak Gupta  Wed, 11 Jun 2014 12:50:30 GMT
Re: Reload Sheet Format

Hi Deepak,

 

Finally, here are some test-files where you test if this also happens to you:

That Sheet property "Region" changes from "Sheet" to "Margins" when using the attached macro.

 

many thanks.

 

/Peter

By: Peter Larsen  Fri, 05 Jan 2018 14:11:03 GMT
Re: Reload Sheet Format

Peter, I do not see anything in the macro that would change it. Can you please report this to your VAR?

By: Deepak Gupta  Sat, 06 Jan 2018 13:38:10 GMT
Re: Reload Sheet Format

Thanks, Deepak - I will contact my VAR.

/Peter

By: Peter Larsen  Wed, 10 Jan 2018 06:47:21 GMT
Re: Reload Sheet Format

Hello Deepak,

 

I am trying to convert this macro into a task so that I can have it reload all the sheet formats during a transition.  I am having trouble with the code to check out the file and then check it back in afterwards.  Any suggestions?

 

Thanks,

 

Garret

By: Garret Hansen  Mon, 12 Feb 2018 23:51:58 GMT
Re: Reload Sheet Format

Okay I figured it out.  If anyone is interested I have attach the code below that you will need to paste into the task script window.

 

Thanks for the help and sharing your code.

 

Deepak Gupta, MARCO TULIO RAMOS FILHO

By: Garret Hansen  Tue, 13 Feb 2018 23:36:47 GMT
Re: Reload Sheet Format

Garret, thanks for sharing.

 

Sorry I had been little busy and could not respond earlier.

By: Deepak Gupta  Wed, 14 Feb 2018 06:05:51 GMT
Re: Reload Sheet Format

No worries.  I couldn't done it without the help and resources on this forum.

By: Garret Hansen  Wed, 14 Feb 2018 19:48:28 GMT
Re: Reload Sheet Format

Hi Garret!

 

Thanx for the feedback and sorry for the absence!

By: MARCO TULIO RAMOS FILHO  Wed, 07 Mar 2018 19:09:24 GMT
You are not authorized to view this page No results found! Suggestions: Check spelling, try a different search, or browse topics below.